include(quasar-common.pri)

QT       += core gui

TARGET = quasar
TEMPLATE = app

#QMAKE_CC   = ccache gcc
#QMAKE_CXX  = ccache g++
#QMAKE_LINK = ccache gcc

DEFINES += USE_NATIVE_FILEDIALOGS USE_FLOAT QT4

CONFIG(debug, debug|release) {
    message("Configuring debug mode...")
    DEFINES += DEBUG
    QMAKE_CFLAGS += -g
    QMAKE_CXXFLAGS += -g
}

CONFIG(release, debug|release) {
    message("Configuring release mode...")
    DEFINES -= DEBUG
}

linux-g++-maemo5 {
    DEFINES += MAEMO USE_LUTLERP

    !debug {
        QMAKE_CFLAGS	+= -O3 -march=armv7-a -mtune=cortex-a8 -mfpu=neon -ftree-vectorize
        QMAKE_CXXFLAGS  += -O3 -march=armv7-a -mtune=cortex-a8 -mfpu=neon -ftree-vectorize
    }

    #INSTALLS += desktop icon64
    #target.path = /usr/bin/quasar
    #desktop.path = /usr/share/applications/hildon
    #desktop.files += distro/skeletons/maemo/quasar.desktop
    #icon64.path = /usr/share/icons/hicolor/64x64/apps
    #icon64.files += distro/images/quasar.png

    # Add files and directories to ship with the application
    # by adapting the examples below.
    # file1.source = myfile
}

win32 {
    QMAKE_LFLAGS += -static-libgcc

    DEFINES += WINDOWS WIN32_SLEEP_DEFINED

    LIBS		-= -lz
    LIBS		+= -lws2_32

    INCLUDEPATH	+= \
            compat/windows

    HEADERS		+= \
            compat/windows/wincompat.h

    RC_FILE		= quasar.rc
}

mac {
    DEFINES += OSX
}

INCLUDEPATH	+= \
        compat/qt4 \
        ui/aspectwidgets/qt4 \
        ui/config/qt4 \
        ui/skin/qt4

HEADERS		-= \
        ui/kineticlistview.h

HEADERS		+= \
        compat/qt4/config.h \
        compat/qt4/resource.h \
        ui/aspectwidgets/qt4/playlistview.h \
        ui/aspectwidgets/qt4/playlistoverview.h \
        ui/config/qt4/formatsconfig.h \
        ui/config/qt4/hotkeyconfig.h \
        ui/skin/qt4/seekbar.h \
        core/aspectextensions/playlistaspectlistviewmodel.h \
    core/aspectextensions/playlistaspectoverviewmodel.h \
    core/aspectextensions/playlistaspectalbumgroupmodel.h

SOURCES		+= \
        compat/qt4/config.cpp \
        compat/qt4/resource.cpp \
        ui/aspectwidgets/qt4/playlistview.cpp \
        ui/aspectwidgets/qt4/playlistoverview.cpp \
        ui/config/qt4/formatsconfig.cpp \
        ui/config/qt4/hotkeyconfig.cpp \
        ui/skin/qt4/seekbar.cpp \
        core/aspectextensions/playlistaspectlistviewmodel.cpp \
    core/aspectextensions/playlistaspectoverviewmodel.cpp \
    core/aspectextensions/playlistaspectalbumgroupmodel.cpp

SOURCES		-= \
        libs/kmdcodec/kmdcodec.cpp \
        ui/kineticlistview.cpp

include(addons/quasar-addons-qt4.pri)

linux-g++-maemo5 {
    skins.source = distro/skins
    DEPLOYMENTFOLDERS += skins
}

# Please do not modify the following two lines. Required for deployment.
include(deployment.pri)
qtcAddDeployment()

linux-g++-maemo5 {
    # overwrite some variables created by qtcAddDeployment()
    desktopfile.files = distro/skeletons/maemo/quasar.desktop
    icon.files = distro/images/quasar.png

    OTHER_FILES += \
        qtc_packaging/debian_fremantle/rules \
        qtc_packaging/debian_fremantle/README \
        qtc_packaging/debian_fremantle/copyright \
        qtc_packaging/debian_fremantle/control \
        qtc_packaging/debian_fremantle/compat \
        qtc_packaging/debian_fremantle/changelog
}